@echo off
setlocal
chcp 65001 >nul 2>&1
title Goldshire Reborn - Client einrichten

set "ROOT=%~dp0"
set "CFG=%ROOT%WTF\Config.wtf"

echo.
echo   ==========================================================
echo     Goldshire Reborn - Client einrichten
echo   ==========================================================
echo.

REM --- Liegt die Datei im Client-Hauptordner? ---
if not exist "%ROOT%Data" goto wrong_folder
if not exist "%ROOT%WoW Circle.exe" goto wrong_folder

REM --- Hat der Client die Config.wtf schon erzeugt? ---
if not exist "%CFG%" goto no_config

REM --- Serveradresse eintragen (bestehende Zeile ersetzen) ---
powershell -NoProfile -ExecutionPolicy Bypass -Command "$q=[char]34;$n='SET portal '+$q+'goldshire-reborn.duckdns.org:3725'+$q;$p='%CFG%';$l=[IO.File]::ReadAllLines($p);$o=New-Object Collections.Generic.List[string];$d=$false;foreach($x in $l){if($x -match '^\s*SET\s+portal\s'){if(-not $d){$o.Add($n);$d=$true}}else{$o.Add($x)}};if(-not $d){$o.Add($n)};[IO.File]::WriteAllLines($p,$o.ToArray(),(New-Object Text.UTF8Encoding $false))"
if errorlevel 1 goto failed

echo   Erledigt. Du bist bereit, auf Goldshire Reborn zu starten.
echo.
echo   Server: goldshire-reborn.duckdns.org:3725
echo.
pause
exit /b 0


:wrong_folder
echo   Bitte diese Datei in den Hauptordner des Clients legen -
echo   direkt neben "WoW Circle.exe" - und dort starten.
echo.
pause
exit /b 1


:no_config
echo   Bitte den Client einmal starten und wieder beenden.
echo   Danach diese Datei erneut ausfuehren.
echo.
pause
exit /b 1


:failed
echo   Die Config.wtf liess sich nicht aendern.
echo   Bitte den Client vollstaendig schliessen und erneut versuchen.
echo.
pause
exit /b 1